Example 1.2. Program to Unpack an OpenOffice.org Document

#!/usr/bin/perl

#
#   Unpack an OpenOffice.org file to a
#   directory.

#
#   Archive::Zip is used to unzip files.
#   File::Path is used to create and remove directories.
#
use Archive::Zip;
use File::Path;
use strict;

my $file_name;
my $dir_name;
my $suffix;
my $zip;
my $member_name;
my @member_list;

if (scalar @ARGV != 1)
{
    print "Usage: $0 filename\n";
    exit;
}

$file_name = $ARGV[0];

#
#   Only allow filenames ending with:
#   .sxw    text
#   .sxc    spreadsheet
#   .sxi    presentation
#   .sxd    drawing
#   .sxg    master
#   .sxm    formula

if ($file_name !~ m/\.s(([xt][wcidm])|(xg))/)
{
    print "This does not appear to be an OpenOffice.org file.\n";
    print "Legal suffixes are .sxw, .sxc, .sxi, .sxd, .sxm, .sxg,\n";
    print ".stw, .stc, .sti, .std, and .stm\n";
    exit;
}

$suffix = $1;

#
#   Create directory name based on filename
#

($dir_name = $file_name) =~ s/(\.s$suffix)//;
$dir_name .= "_s$suffix";

#
#   Forcibly remove old directory, re-create it,
#   and unzip the OpenOffice.org file into that directory
#
rmtree($dir_name, 0, 0);
mkpath($dir_name, 0, 0755);

$zip = Archive::Zip->new( $file_name );
@member_list = $zip->memberNames( );

foreach $member_name (@member_list)
{
    $zip->extractMember( $member_name, "$dir_name/$member_name" );
}

print "$file_name unpacked.\n";

Example 1.3. Program to Pack Files to Create an OpenOffice.org Document

#!/usr/bin/perl

#
#   Repack a directory to an OpenOffice.org file
#
#   Directory xyz_sxw will be packed into xyz.sxw, etc.
#

if (scalar @ARGV < 1 || scalar @ARGV > 2)
{
    print "Usage: $0 directoryname [newfilename]\n";
    exit;
}

$dir_name = $ARGV[0];


#
#   If no new filename is given, create a filename
#   based on directory name
#

if ($ARGV[1])
{
    $file_name = $ARGV[1];
}
else
{
    if ($dir_name !~ m/_s(([xt][wcidm])|(xg))/)
    {
        print "This does not appear to be an unpacked OpenOffice.org file.\n";
        print "Legal suffixes are _sxw, _sxc, _sxi, _sxd, _sxm, _sxg,\n";
        print "_stw, _stc, _sti, _std, and _stm.\n";
        exit;
    }

    $suffix = $1;
    ($file_name = $dir_name) =~ s/(_s$suffix)//;
    $file_name .= ".s$suffix";
}

$current_dir = `pwd`;
if (!chdir($dir_name))
{
    print "Cannot change to directory $dir_name\n";
    exit;
}

system("zip -r ../$file_name *");

chdir($current_dir);

print "$dir_name packed to $file_name.\n";